10 REM ***** CASH FLOW EVALUATION *****
11 POKE53280,1:POKE53281,1:POKE53272,21
12 PRINT"[144][147]  ****  CASH FLOW EVALUATION [146] ****"
14 IF P2$="Y" THEN 20
15 IF P$="Y" OR P$="N" THEN 20
16 PRINT"DO YOU HAVE A PRINTER (Y/N)";:INPUT P$
17 IF P$="Y" OR P$="N" THEN 20
18 GOTO16
20 PRINT"CLIENT NAME =";
22 INPUT CN$
24 PRINT"PROPERTY IDENTIFICATION =";
26 INPUT PN$
28 IF P$ ="Y" THEN GOSUB 1000
30 PRINT "REAL ESTATE COST";
32 INPUT C
40 PRINT "MORTGAGE DOWN PAYMENT (% OF COST)";
50 INPUT P
60 PRINT"LOAN TERM (YEARS)";
70 INPUT Y
80 PRINT "CLOSING COSTS- POINTS (% OF COST)";
90 INPUT F
100 PRINT "MORTGAGE INTEREST RATE (%)";
110 INPUT R
120 PRINT "ADDITIONAL INITIAL COSTS";
130 INPUT I
140 PRINT "REAL ESTATE TAX PER YEAR";
150 INPUT T
160 PRINT "HEATING COSTS PER YEAR";
170 INPUT H
180 PRINT "ELECTRICITY COST PER MONTH";
190 INPUT E
200 PRINT "INSURANCE, WATER, MAINT.,ETC. PER MONTH";
210 INPUT A
220 PRINT "INCOME PER MONTH";
230 INPUT Z
232 IF P$="Y" THEN GOSUB 1020
240 L4=C-(C*(P/100))
250 T4=1+R/1200
260 M=L4*(((R/1200)*T4^(Y*12))/((T4^(Y*12))-1))
270 PRINT"[147]              CASH FLOW ANALYSIS"
280 PRINT
290 PRINT "MONTHLY MORTGAGE PAYMENTS = $";INT(100*M)/100
300 PRINT "MONTHLY TAX PAYMENTS      = $";INT(100*(T/12))/100
310 PRINT "MONTHLY EXPENSES          = $";INT(100*((H/12)+E+A))/100
320 PRINT
330 PRINT "MONTHLY INCOME            = $";INT(100*Z)/100
340 PRINT
350 X=(M+(T/12)+(H/12)+E+A)
360 PRINT "---------------------------------------"
370 PRINT "MONTHLY CASH FLOW         = $";INT(100*(Z-X))/100
380 IF Z-X<O THEN 400
390 GOTO 410
400 PRINT"----------- WARNING NEGATIVE CASH FLOW"
410 PRINT "---------------------------------------"
420 PRINT
430 PRINT
440 PRINT
444 IF P$="Y" THEN GOSUB 2200
450 REM ***** TAX DEDUCTION INFO *****
460 PRINT "WANT TAX DEDUCTION INFORMATION (Y/N)";:INPUT T$
462 IF T$="Y" THEN 480
464 IF T$="N" THEN 9000
469 GOTO 460
480 I4=L4*R/100
490 PRINT "APPROX. VALUE OF LAND";
500 INPUT V
510 PRINT "APPROX. TAX BRACKET (% OF INCOME)";
520 INPUT B4
530 PRINT "NEW (1) OR USED (2) BUILDING";
540 INPUT U
542 IF P$="Y" THEN GOSUB 3000
550 IF U=1 THEN 580
560 U1=1.25
570 GOTO 590
580 U1=2
590 D=U1*((C-V)/20)
600 G4=(H/12)+E+A+((F/100)*L4/12)
610 PRINT
620 PRINT
630 PRINT"             INVESTMENT TAX ADVANTAGE"
640 PRINT
650 PRINT "DEDUCTABLE INTEREST= $";INT(100*I4)/100;"FIRST YEAR"
660 PRINT "REAL ESTATE TAXES  = $";INT(100*T)/100;"PER YEAR"
670 PRINT "DEPRECIATION       = $";INT(100*D)/100;"FIRST YEAR"
680 PRINT "EXPENCES           = $";INT(100*G4*12)/100;"FIRST YEAR"
690 PRINT
700 PRINT "TOTAL DEDUCTABLE = $";INT(100*(I4+T+D+12*(G4)))/100;"1ST YR"
710 PRINT "TOTAL INCOME    = $";INT(100*Z*12)/100;"PER YEAR"
720 J4=(I4+D+T+(G4*12))-Z*12
730 PRINT
740 PRINT "NET DEDUCTION   = $";INT(100*J4)/100
750 T5=J4*(B4/100)
760 PRINT
770 PRINT "---------------------------------------"
780 IF T5<O THEN 810
790 PRINT "FIRST YEAR TAX BREAK =$";INT(100*T5)/100
800 GOTO 830
810 PRINT "NO TAX BREAK"
820 T5=O
830 I5=(P/100*C)+(F/100*C)+I-((Z-X)*12)
840 PRINT "---------------------------------------"
850 PRINT
860 PRINT
870 PRINT "RETURN ON INVESTMENT = "INT(((((Z-X)*12)+T5)/I5)*100);"%"
880 IF P$ ="Y" THEN GOSUB 4000
890 GOTO 9000
1000 REM *** INITIALIZE PRINTER ***
1001 IF P2$="Y" THEN 1004
1002 OPEN4,4,1
1004 PRINT#4:PRINT#4,"  ******  CASH FLOW EVALUATION  ******"
1010 PRINT#4:PRINT#4,"CLIENT NAME = ";CN$
1014 PRINT#4:PRINT#4,"PROPERTY IDENTIFICATION = ";PN$
1019 RETURN
1020 REM **** PRINT INPUT DATA ****
1030 PRINT#4:PRINT#4,"REAL ESTATE COST $";C
1040 PRINT#4:PRINT#4,"MORTGAGE DOWN PAYMENT";P;"% OF COST"
1060 PRINT#4:PRINT#4,"LOAN TERM =";Y;" YEARS"
1080 PRINT#4:PRINT#4,"CLOSING COSTS - POINTS";F;"% OF COST"
1100 PRINT#4:PRINT#4,"MORTGAGE INTEREST RATE";R;"%"
1120 PRINT#4:PRINT#4,"ADDITIONAL INITIAL COSTS = $";I
1140 PRINT#4:PRINT#4,"REAL ESTATE TAX PER YEAR = $";T
1160 PRINT#4:PRINT#4,"HEATING COSTS PER YEAR = $";H
1180 PRINT#4:PRINT#4,"ELECTRICITY COST PER YEAR = $";E
1200 PRINT#4:PRINT#4,"INSURANCE, WATER, MAINT.,ETC. = $";A;" PER MONTH"
1220 PRINT#4:PRINT#4,"INCOME PER MONTH = $";Z
1290 RETURN
2200 REM *** PRINT CASH FLOW ANALYSIS **
2210 PRINT#4:PRINT#4
2270 PRINT#4:PRINT#4,"                CASH FLOW ANALYSIS"
2280 PRINT#4
2290 PRINT#4,"MONTHLY MORTGAGE PAYMENTS = $";INT(100*M)/100
2300 PRINT#4:PRINT#4,"MONTHLY TAX PAYMENTS      = $";INT(100*(T/12))/100
2310 PRINT#4:PRINT#4,"MONTHLY EXPENSES          = $";INT(100*((H/12)+E+A))/100
2320 PRINT#4
2330 PRINT#4,"MONTHLY INCOME            = $";INT(100*Z)/100
2340 PRINT#4
2360 PRINT#4,"---------------------------------------------------"
2370 PRINT#4:PRINT#4,"MONTHLY CASH FLOW         = $";INT(100*(Z-X))/100
2380 IF Z-X<O THEN 2400
2390 GOTO 2410
2400 PRINT#4:PRINT#4,"- - - - - - WARNING NEGATIVE CASH FLOW"
2410 PRINT#4:PRINT#4,"---------------------------------------------------"
2420 PRINT#4
2430 PRINT#4
2440 PRINT#4
2500 RETURN
3000 REM ***** TAX DEDUCTION INFO ****
3100 PRINT#4:PRINT#4,"          TAX DEDUCTION INFORMATION"
3400 PRINT#4
3490 PRINT#4:PRINT#4,"APPROX. VALUE OF LAND = $";V
3510 PRINT#4:PRINT#4,"APPROX. TAX BRACKET =";B4;"% OF INCOME"
3530 PRINT#4:PRINT#4,"NEW (1) OR USED (2) BUILDING -";U
3900 RETURN
4000 REM *** PRINT TAX ADVANTAGE ***
4010 PRINT#4
4020 PRINT#4
4030 PRINT#4,"             INVESTMENT TAX ADVANTAGE"
4040 PRINT#4
4050 PRINT#4:PRINT#4,"DEDUCTABLE INTEREST = $";INT(100*I4)/100;" FIRST YEAR"
4060 PRINT#4:PRINT#4,"REAL ESTATE TAXES   = $";INT(100*T)/100;" PER YEAR"
4070 PRINT#4:PRINT#4,"DEPRECIATION        = $";INT(100*D)/100;" FIRST YEAR"
4080 PRINT#4:PRINT#4,"EXPENCES            = $";INT(100*G4*12)/100;" FIRST YEAR"
4090 PRINT#4:PRINT#4
4100 PRINT#4,"TOTAL DEDUCTABLE = $";INT(100*(I4+T+D+12*(G4)))/100;" 1ST YR"
4110 PRINT#4:PRINT#4,"TOTAL INCOME    = $";INT(100*Z*12)/100;" PER YEAR"
4130 PRINT#4
4140 PRINT#4:PRINT#4,"NET DEDUCTION   = $";INT(100*J4)/100
4160 PRINT#4
4170 PRINT#4,"---------------------------------------------------"
4180 IF T5<O THEN 4210
4190 PRINT#4:PRINT#4,"FIRST YEAR TAX BREAK = $";INT(100*T5)/100
4200 GOTO 4240
4210 PRINT#4:PRINT#4,"NO TAX BREAK"
4240 PRINT#4:PRINT#4,"---------------------------------------------------"
4250 PRINT#4
4260 PRINT#4
4270 PRINT#4,"RETURN ON INVESTMENT = "INT(((((Z-X)*12)+T5)/I5)*100);"%"
4900 RETURN
9000 REM *** END ***
9100 PRINT"DO YOU WANT TO EVALUATE ANOTHER PROPERTY (Y/N)":INPUT P2$
9110 IF P2$="Y"THEN 10
9120 IF P2$<>"N"THEN 9100
9200 PRINT"HOPE THIS WAS OF SOME HELP"
9300 CLOSE4
9990 END